Page 1 sur 2
Creation batch pour tailles des icones
Posté : 27 janv. 2018 00:15
par shakes
Bonjour,
Je souhaiterais pouvoir créer un petit batch en DOS (si c'est possible) qui permettrait que certains dossiers puissent voir leur icone être en "tres grande icones" ou" moyen icones" etc.
Le top serait que je puisse lancer le batch dans un endroit d'un disque dur par exemple et que tous les répertoires et sous répertoires uniquement passe en tres grand icones ou grand icones mais que le reste reste en mode normal.
Question : Est-ce possible et si oui quel en est la fonction ?
Merci d'avance.
Re: Creation batch pour tailles des icones
Posté : 01 févr. 2018 15:33
par shakes
Petit Up !
Personne ne sait ou ce n'est pas possible ?
Merci à vous
Re: Creation batch pour tailles des icones
Posté : 11 févr. 2018 05:10
par Hackoo
Salut
J'ai vu l'astuce dans un forum anglais :
Change Desktop icon size via registry, alors j'ai pensé de faire ce petit batch avec un menu dynamique qui vous permet de bascluer et choisir la taille de vos icônes sur le bureau
Donc à tester chez vous
Code : Tout sélectionner
@echo off & >nul chcp 65001
Title Changer la taille des icônes sur le bureau by Hackoo 2018
set "Key=HKCU\Software\Microsoft\Windows\Shell\Bags\1\Desktop"
:MenuLOOP
Cls & Color 9E & Mode con cols=87 lines=11
echo(
echo( ============================== Menu ================================
echo(
for /f "tokens=2* delims=_ " %%A in ('"findstr /bi /c:":Menu_" "%~f0""') do (
echo %%A %%B )
echo(
echo( ====================================================================
set choice=
echo( & set /p choice=Faites un choix entre 1 , 2 , 3 ou appuyez sur ENTER pour quitter : || GOTO :EOF
echo( & call :Menu_[%choice%]
GOTO MenuLOOP
::*************************************************************
:Menu_[1] Icônes avec une taille Grandes
cls & echo(
echo Changement de la taille des icônes en taille grandes ...
echo(
set /a "BigSize=96"
reg add "%Key%" /v "IconSize" /t REG_DWORD /d %BigSize% /f
goto RefreshExplorer
::*************************************************************
:Menu_[2] Icônes avec une taille Moyennes
cls & echo(
echo Changement de la taille des icônes en taille moyennes ...
echo(
set /a "MediumSize=48"
reg add "%Key%" /v "IconSize" /t REG_DWORD /d %MediumSize% /f
goto RefreshExplorer
::*************************************************************
:Menu_[3] Icônes avec une taille Petites
cls & echo(
echo Changement de la taille des icônes en taille petites ...
echo(
set /a "LittleSize=32"
reg add "%Key%" /v "IconSize" /t REG_DWORD /d %LittleSize% /f
goto RefreshExplorer
::*************************************************************
:RefreshExplorer
Taskkill /f /im explorer.exe>nul 2>&1
Timeout /T 4 /nobreak>nul
Start "" "explorer.exe"
GOTO MenuLOOP
::*************************************************************
Re: Creation batch pour tailles des icones
Posté : 13 févr. 2018 12:05
par shakes
Merci. Par contre, je ne vais pas très loin, j'ai une pop up bleu puis on sort du .bat
On me demande pas le choix comme dans le script ...
Re: Creation batch pour tailles des icones
Posté : 13 févr. 2018 21:18
par Hackoo
shakes a écrit :Merci. Par contre, je ne vais pas très loin, j'ai une pop up bleu puis on sort du .bat
On me demande pas le choix comme dans le script ...
Est-ce-que tu as modifié quelques chose dans le code ?
Car chez moi ça marche très bien !
Si oui, poster moi le code modifié !
Re: Creation batch pour tailles des icones
Posté : 14 févr. 2018 13:10
par shakes
Non, je n'ai rien modifié. j'ai juste fais un copier/coller dans un .Bat et lancé sous WIndows 7
Re: Creation batch pour tailles des icones
Posté : 15 févr. 2018 02:29
par Hackoo
Tester ce nouveau code et un grand merci a mon pote Sacha pour la modification apporté sur le menu dynamique
Code : Tout sélectionner
@echo off & >nul chcp 65001
Color 9E & Mode con cols=87 lines=11
setlocal enabledelayedexpansion
Title Changer la taille des icônes sur le bureau by Hackoo 2018
Rem Modification du Menu par Sachadee (un grand merci à lui)
Rem http://batch.xoo.it/t5973-Changer-la-taille-des-ic-nes-du-bureau.htm#p44826
set "Key=HKCU\Software\Microsoft\Windows\Shell\Bags\1\Desktop"
:MenuLOOP
cls
Set "$char="
echo.
echo. ============================== Menu ================================
echo.
echo. Faites un choix entre 1 a 9 ou appuyez sur ENTER pour quitter :
echo.
echo. ====================================================================
For /F "delims=" %%# In ('Xcopy /W "%~f0" "%~f0" 2^>Nul') Do If Not Defined $char Set "$char=%%#"
Set "$char=%$char:~-1%"
if not defined $char exit/b
call :Menu %$char%
GOTO MenuLOOP
::*************************************************************
:Menu
set /a $val=96/%1 2>nul && (
echo Changement de la taille des icônes en taille !taille!
reg add "%Key%" /v "IconSize" /t REG_DWORD /d !$val! /f
call:RefreshExplorer
Set "$val="
)
exit/b
::*************************************************************
:RefreshExplorer
Taskkill /f /im explorer.exe>nul 2>&1
Timeout /T 4 /nobreak>nul
Start "" "explorer.exe"
::*************************************************************
Re: Creation batch pour tailles des icones
Posté : 15 févr. 2018 12:16
par shakes
Alors maintenant je peux faire un choix effectivement mais quelque soit mon choix (de 1 à 9), il n'y a aucun changement qui se produit.
Re: Creation batch pour tailles des icones
Posté : 15 févr. 2018 12:20
par Hackoo
shakes a écrit :Alors maintenant je peux faire un choix effectivement mais quelque soit mon choix (de 1 à 9), il n'y a aucun changement qui se produit.
il modifie juste les icônes de votre bureau !
Re: Creation batch pour tailles des icones
Posté : 16 févr. 2018 09:51
par shakes
Oui mais meme ca